Fungsi SUMIF

Tutorial kelas excel ini membahas tentang fungsi SUMIF lengkap dengan syntax dan contohnya.

Fungsi SUMIF ini termasuk dalam kategori fungsi matematika di excel.

Deskripsi

SUMIF adalah fungsi excel untuk menjumlahkan data tapi dengan menggunakan suatu kondisi tertentu.

Kriteria kondisi tersebut bisa berupa angka, tanggal atau teks.

Fungsi SUMIF ini juga mendukung logika operator seperti =, >, <, <> serta wildcard juga untuk partial matching (mencocokkan sebagian).

Contoh wildcard misalnya: mencari data yang awalannya huruf R.

Penggunaan

Menjumlahkan angka dengan kondisi tertentu.

Nilai yang Dihasilkan

Hasil penjumlahan data.

Sintaksis

Berikut adalah syntax penulisan fungsi SUMIF:

=SUMIF(range; criteria; [sum_range])

Argumen

Fungsi SUMIF memiliki argumen berikut:

• range wajib – range cell (misal: A1-B3) yang berisikan data untuk dihitung.
• criteria wajib – kriteria kondisi yang ditentukan (misal data >10).
• sum_range tidak wajib – sel tambahan yang akan dihitung jika kriteria terpenuhi, jika sum_range tidak ada maka data yang dihitung adalah data dalam range.

Catatan

• SUMIF harus berupa range tidak bisa diganti dengan array.
• SUMIF hanya mendukung satu kriteria saja, jika banyak kriteria maka gunakan fungsi SUMIFS.
• Jika dalam argumen criteria ada data berbentuk string, maka harus menggunakan tanda petik “”, contoh “>20”.
• Jika dalam criteria memuat string dan cell, maka cukup stringnya saja yang ada tanda petik “”, contoh ">"&A3.

Contoh

Berikut example dari fungsi SUMIF untuk berbagai skenario implementasi.

Contoh SUMIF Angka Penjualan

Intepretasi contoh SUMIF di atas sebagai berikut:

Ada data tabel, dengan kolom Harga Jual (range) , Komisi (sum_range) dan Minimal Komisi (criteria).

Formula SUMIF	Hasil	Keterangan
=SUMIF(A2:A5;">450000")	26.000.000	Menghitung semua harga jual yang > Rp 450.000
=SUMIF(A2:A5;">450000";B2:B5)	2.600.000	Menghitung total komisi dimana harga jual > Rp 450.000
=SUMIF(A2:A5;7000000;B2:B5)	700.000	Menghitung total komisi dimana harga jual = Rp 7.000.0000
=SUMIF(A2:A5;">"&C2;B2:B5)	2.100.000	Menghitung total komisi dimana harga jual > Rp 5.500.000 (C2)

Contoh SUMIF dengan Teks

Berikut adalah example SUMIF jika menggunakan data kriteria berupa teks:

Di atas ada data penjualan gawai, ada empat kolom yaitu kategori, merk gadget, kode dan data total penjualan.

Yang menjadi sum_range adalah kolom penjualan, karena yang lainnya data berupa teks.

Formula	Hasil	Keterangan
=SUMIF(A2:A6;"Smartphone";D2:D6)	10.200.000.000	Menjumlahkan semua penjualan kategori smartphone.
=SUMIF(A2:A7;"";D2:D7)	500.000.000	Menghitung semua yang tidak berkategori (cell blank / kolom kosong)
=SUMIF(C2:C7;"SP*";D2:D7)	10.200.000.000	Menjumlah semua penjualan yang kodenya berawalan SP (menggunakan fitur wildcards).

Contoh SUMIF Tanggal

Kita juga bisa menjumlahkan dengan criteria berupa tanggal.

Formula	Hasil	Keterangan
=SUMIF(A2:A13;">"&DATE(2021;1;31);B2:B13)	65.200.000	Menjumlahkan penjualan setelah bulan januari
=SUMIF(A2:A13;"<"&DATE(2021;3;1);B2:B13)	18.000.000	Menjumlahkan penjualan sebelum bulan maret
=SUMIF(A2:A13;"<"&D7;B2:B13)	27.000.000	Menjumlahkan sebelum tanggal 15 Maret 2021.